*     PRCUPDAT
*-----------------------------------------------------------------------
*
*     Object :
*     Example program for subroutine PRCUPDAT (Fortran 77, DOS 5.0).
*     Read comments in subroutine PRCUPDAT.
*
*-----------------------------------------------------------------------
*
      implicit double precision (a-h,o-z)
      character*7 escscr
      escscr=char(27)//char(91)//'2J'//char(27)//char(91)//'H'
*
*     New values for masses of planets (IERS standard 1992).
*
      rme=6023600.d0
      rve=408523.71d0
      rma=3098708.d0
      rju=1047.3486d0
      rsa=3497.90d0
      rur=22902.94d0
      rne=19412.24d0
      nlu=10
*
      call PRCUPDAT (prc,obl,rme,rve,rma,rju,rsa,rur,rne,nlu)
      write (*,'(2x,a)') escscr
      write (*,1000)
1000  format (////2x,'PROGRAM  PRCUPDAT'
     .        ////2x,'The file NEWPRC.DAT contains the new numerical ',
     .        'expressions of precession'
     .        ////2x,'End of program'//////)
*
      stop1248
      end
*
*
*
      subroutine PRCUPDAT (prc,obl,rme,rve,rma,rju,rsa,rur,rne,nlu)
*-----------------------------------------------------------------------
*
*     *******
*     Warning : this subroutine creates or modifies the output file NEWPRC.DAT.
*     *******
*
*     Object :
*     Improvement of numerical expressions of precession built at Bureau
*     des Longitudes (1994) with new values for following constants :
*     - general precession,
*     - obliquity in J2000,
*     - ratios  Sun mass / planet mass.
*
*     Reference :
*     Astron. Astrophys. 282, 663 (1994).
*
*     Authors :
*     J.L. Simon, P. Bretagnon, J. Chapront, M. Chapront-Touze,
*     G. Francou, J. Laskar (Bureau des Longitudes, Paris, France).
*
*     Input parameters :
*     prc   general precession in "/1000y (double real).
*     obl   obliquity J2000 in arcseconds (double real).
*     rme   ratio mass Mercury / mass Sun (double real)
*     rve   ratio mass Venus   / mass Sun (double real)
*     rma   ratio mass Mars    / mass Sun (double real)
*     rju   ratio mass Jupiter / mass Sun (double real)
*     rsa   ratio mass Saturn  / mass Sun (double real)
*     rur   ratio mass Uranus  / mass Sun (double real)
*     rne   ratio mass Neptune / mass Sun (double real)
*     nlu   logical unit of output file (integer)
*
*     Output file :
*     File name : NEWPRC.DAT (sequential, record length : 80 bytes).
*     This file contains the new numerical expressions of precession
*     written under the form of data instructions in Fortran 77.
*
*     Remark :
*     The default values of constants used in the original formulae are
*     kept if the corresponding subroutine parameters are set to zero.
*     Default values :
*     general precession :                50288.200 "/1000y.
*     obliquity in J2000 :                84381.412 " (23x26'21.412").
*     Ratio  Sun mass / Mercury mass :    6023600     IAU 1976
*     Ratio  Sun mass / Venus   mass :    408523.5    IAU 1976
*     Ratio  Sun mass / E-M baryc. mass : 328900.5    IAU 1976
*     Ratio  Sun mass / Mars    mass :    3098710     IAU 1976
*     Ratio  Sun mass / Jupiter mass :    1047.355    IAU 1976
*     Ratio  Sun mass / Saturn mass :     3498.5      IAU 1976
*     Ratio  Sun mass / Uranus  mass :    22869       IAU 1976
*     Ratio  Sun mass / Neptune mass :    19314       IAU 1976
*     An error on the Earth-Moon barycenter mass is considered too small
*     for having influence on the numerical expressions of precession.
*
*     Notations :
*     For each array hereunder, the indices correspond respectively to
*     coefficients of power of time :
*               T = (fixed epoch - J2000 epoch)
*          and  t = (epoch of the date - fixed epoch)
*          in thousands of Julian years of 365250 days.
*     These coefficients are double real expressed in 1/10000 ".
*     ss    (0:5,1:5) :   sin(pi.a)*sin(PI.a)
*     sc    (0:5,1:5) :   sin(pi.a)*cos(PI.a)
*     spi   (0:5,1:4) :   pi.a
*     cpi   (0:5,0:5) :   PI.a
*     p     (0:5,1:6) :   p.a (precession)
*     epsil (0:5,0:5) :   epsilon.a (obliquity)
*     theta (0:5,1:6) :   theta.a
*     zeta  (0:5,1:6) :   zeta.a
*     z     (0:5,1:6) :   z.a
*     omega (0:5,0:6) :   omega.a
*     psi   (0:5,1:6) :   psi.a
*     chi   (0:5,1:6) :   chi.a
*
*-----------------------------------------------------------------------
*
*     Declarations.
*
      implicit double precision (a-h,o-z)
      logical fexist
      dimension ss(0:5,5),sc(0:5,5)
      dimension spi(0:5,4),cpi(0:5,0:5),p(0:5,6)
      dimension theta(0:5,6),zeta(0:5,6),z(0:5,6)
      dimension epsil(0:5,0:5),omega(0:5,0:6),psi(0:5,6),chi(0:5,6)
*
*     Original numerical expressions of precession.
*
      data ss/
     .    419971.d0,  -753286.d0,   3179.d0,  3178.d0,    7.d0,   -4.d0, T0-5 t1
     .    193971.d0,     5740.d0,  -2541.d0,    -5.d0,    6.d0,    0.d0, T0-4 t2
     .     -2235.d0,      859.d0,     33.d0,    -3.d0,    0.d0,    0.d0, T0-3 t3
     .      -104.d0,       -4.d0,      2.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .         2.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t5
      data sc/
     .  -4680927.d0,     -305.d0,  59967.d0,  -205.d0, -125.d0,   -2.d0, T0-5 t1
     .     51043.d0,   -31633.d0,   -326.d0,   138.d0,   -2.d0,    0.d0, T0-4 t2
     .      5223.d0,      318.d0,    -66.d0,    -4.d0,    0.d0,    0.d0, T0-3 t3
     .       -57.d0,       19.d0,     -1.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .        -1.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t5
      data spi/
     .   4699729.d0,   -67011.d0,    448.d0,   -19.d0,   -1.d0,    0.d0, T0-4 t1
     .    -33505.d0,      448.d0,    -28.d0,    -2.d0,    1.d0,    0.d0, T0-4 t2
     .     -1237.d0,       -4.d0,     -2.d0,     1.d0,    0.d0,    0.d0, T0-3 t3
     .         3.d0,       -1.d0,      1.d0,     0.d0,    0.d0,    0.d0/ T0-2 t4
      data cpi/
     .6295434330.d0,329296590.d0, 953520.d0,   -50.d0,-4590.d0, -100.d0, T0-5 t0
     . -86792700.d0,  -158510.d0,  -1130.d0, -4480.d0, -190.d0,    0.d0, T0-4 t1
     .    153420.d0,     -190.d0,  -4320.d0,  -230.d0,    0.d0,    0.d0, T0-3 t2
     .        50.d0,    -2080.d0,   -150.d0,     0.d0,    0.d0,    0.d0, T0-2 t3
     .      -370.d0,      -50.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t4
     .       -10.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t5
      data p/
     . 502882000.d0,  2224045.d0,   2095.d0, -9408.d0,  -90.d0,   10.d0, T0-5 t1
     .   1112022.d0,     2095.d0, -14111.d0,  -180.d0,   26.d0,    0.d0, T0-4 t2
     .       773.d0,    -9410.d0,   -180.d0,    35.d0,    0.d0,    0.d0, T0-3 t3
     .     -2353.d0,      -90.d0,     26.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .       -18.d0,       10.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t5
     .         2.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
      data theta/
     . 200420207.d0,  -853131.d0,  -2111.d0,  3642.d0,    8.d0,   -5.d0, T0-5 t1
     .   -426566.d0,    -2111.d0,   5463.d0,    17.d0,  -12.d0,    0.d0, T0-4 t2
     .   -418238.d0,      359.d0,     27.d0,    -1.d0,    0.d0,    0.d0, T0-3 t3
     .      -731.d0,       19.d0,      9.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .      -127.d0,       11.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t5
     .         4.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
      data zeta/
     . 230609097.d0,  1397495.d0,    -38.d0, -5918.d0,  -37.d0,    7.d0, T0-5 t1
     .    302226.d0,    -2523.d0,  -3840.d0,   -14.d0,    7.d0,    0.d0, T0-4 t2
     .    180183.d0,    -1326.d0,      6.d0,     5.d0,    0.d0,    0.d0, T0-3 t3
     .      -583.d0,       -1.d0,      7.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .      -285.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0   t5
     .        -2.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
      data z/
     . 230609097.d0,  1397495.d0,    -38.d0, -5918.d0,  -37.d0,    7.d0, T0-5 t1
     .   1095270.d0,     2446.d0, -13913.d0,  -134.d0,   26.d0,    0.d0, T0-4 t2
     .    182667.d0,   -11400.d0,   -173.d0,    44.d0,    0.d0,    0.d0, T0-3 t3
     .     -2821.d0,      -93.d0,     32.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .      -301.d0,        6.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t5
     .        -1.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
      data epsil/
     . 843814120.d0, -4680927.d0,   -152.d0, 19989.d0,  -51.d0,  -25.d0, T0-5 t0
     .  -4680927.d0,     -305.d0,  59967.d0,  -205.d0, -125.d0,   -2.d0, T0-5 t1
     .      -152.d0,    59967.d0,   -308.d0,  -250.d0,   -6.d0,    0.d0, T0-4 t2
     .     19989.d0,     -205.d0,   -250.d0,    -8.d0,    0.d0,    0.d0, T0-3 t3
     .       -51.d0,     -125.d0,     -6.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .       -25.d0,       -2.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0-1 t5
      data omega/
     . 843814120.d0, -4680927.d0,   -152.d0, 19989.d0,  -51.d0,  -25.d0, T0-5 t0
     .         0.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0,      t1
     .     51294.d0,   -91954.d0,    298.d0,   389.d0,    2.d0,    0.d0, T0-4 t2
     .    -77276.d0,      235.d0,    987.d0,    -1.d0,    0.d0,    0.d0, T0-3 t3
     .       -48.d0,      954.d0,     -7.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .       333.d0,       -9.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t5
     .        -3.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
      data psi/
     . 503850672.d0,   492595.d0,  -1344.d0, -2115.d0,   17.d0,    3.d0, T0-5 t1
     .  -1072374.d0,   -10919.d0,  13673.d0,   137.d0,  -28.d0,    0.d0, T0-4 t2
     .    -11424.d0,    26425.d0,     87.d0,  -111.d0,    0.d0,    0.d0, T0-3 t3
     .     13279.d0,     -110.d0,   -170.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .       -94.d0,     -123.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t5
     .       -35.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
      data chi/
     .   1055794.d0, -1888214.d0,  -1888.d0, +7950.d0,  101.d0,   -9.d0, T0-5 t1
     .  -2381379.d0,   -10910.d0,  30291.d0,  +290.d0,  -59.d0,    0.d0, T0-4 t2
     .    -12117.d0,    39055.d0,    229.d0,  -159.d0,    0.d0,    0.d0, T0-3 t3
     .     17024.d0,      -38.d0,   -214.d0,     0.d0,    0.d0,    0.d0, T0-2 t4
     .       -77.d0,     -145.d0,      0.d0,     0.d0,    0.d0,    0.d0, T0-1 t5
     .       -40.d0,        0.d0,      0.d0,     0.d0,    0.d0,    0.d0/ T0   t6
*
*     Default values of constants.
*
      data prc0/50288.200d0/
      data obl0/84381.412d0/
      data rme0/6023600.d0/
      data rve0/408523.5d0/
      data rma0/3098710.d0/
      data rju0/1047.355d0/
      data rsa0/3498.5d0/
      data rur0/22869.d0/
      data rne0/19314.d0/
*
*     Initialization of corrections.
*
      data zero/0.d0/,dp/0.d0/,de/0.d0/,dme/0.d0/,dve/0.d0/
      data dma/0.d0/,dju/0.d0/,dsa/0.d0/,dur/0.d0/,dne/0.d0/
      if (prc.ne.zero) then
         dp=prc-prc0
         prc0=prc
      endif
      if (obl.ne.zero) then
         de=obl-obl0
         obl0=obl
      endif
      if (rme.ne.zero) then
         dme=-(rme-rme0)/rme0
         rme0=rme
      endif
      if (rve.ne.zero) then
         dve=-(rve-rve0)/rve0
         rve0=rve
      endif
      if (rme.ne.zero) then
         dma=-(rma-rma0)/rma0
         rma0=rma
      endif
      if (rju.ne.zero) then
         dju=-(rju-rju0)/rju0
         rju0=rju
      endif
      if (rsa.ne.zero) then
         dsa=-(rsa-rsa0)/rsa0
         rsa0=rsa
      endif
      if (rur.ne.zero) then
         dur=-(rur-rur0)/rur0
         rur0=rur
      endif
      if (rne.ne.zero) then
         dne=-(rne-rne0)/rne0
         rne0=rne
      endif
*
*     Corrections of numerical expressions of precession.
*
      ss(0,1)=ss(0,1)                                                    T0 t1
     +  +3.0d4*dme-29.d4*dju-5.7d4*dsa-0.04d4*dne
      ss(1,1)=ss(1,1)                                                    T1 t1
     +  -0.0023d4*dp
     +  -39.d4*dju-3.1d4*dsa
      sc(0,1)=sc(0,1)                                                    T0 t1
     +  -2.7d4*dme-286.d4*dve-159.d4*dju-13.0d4*dsa-0.04d4*dne
      sc(1,1)=sc(1,1)                                                    T1 t1
     +  +1.4d4*dsa
      sc(2,1)=sc(2,1)                                                    T2 t1
     +  +0.0004d4*dp
      spi(0,1)=spi(0,1)                                                  T0 t1
     +  +3.0d4*dme+291.d4*dve+156.d4*dju+12.4d4*dsa+0.04d4*dne
      cpi(0,0)=cpi(0,0)                                                  T0 t0
     +  -1228.d4*dme-18371.d4*dve-2410.d4*dma+18994.d4*dju+2995.d4*dsa
     +  -7.d4*dur+18.3d4*dne
      cpi(1,0)=cpi(1,0)                                                  T1 t0
     +  +dp
     +  +92.d4*dme+10490.d4*dve+6018.d4*dju+502.d4*dsa+3.d4*dur
     +  +1.8d4*dne
      cpi(2,0)=cpi(2,0)                                                  T2 t0
     +  +0.003d4*dp
      cpi(0,1)=cpi(0,1)                                                  T0 t1
     +  +46.d4*dme+5245.d4*dve+3009.d4*dju+251.d4*dsa+1.5d4*dur
     +  +0.9d4*dne
      p(0,1)=p(0,1)                                                      T0 t1
     +  +dp
      p(1,1)=p(1,1)                                                      T1 t1
     +  +0.0062d4*dp-0.0016d4*de
     +  +1.8d4*dme+190.d4*dve+106.d4*dju+8.7d4*dsa+0.03d4*dne
      p(0,2)=p(0,2)                                                      T0 t2
     +  +0.0031d4*dp
     +  +53.d4*dju+4.4d4*dsa
      theta(0,1)=theta(0,1)                                              T0 t1
     +  +0.3978d4*dp+0.2236d4*de
     +  +2.8d4*dme-27.d4*dju-5.2d4*dsa-0.03d4*dne
      theta(1,1)=theta(1,1)                                              T1 t1
     +  -0.0017d4*dp
     +  -29.d4*dju-2.3d4*dsa
      theta(0,2)=theta(0,2)                                              T0 t2
     +  -0.0008d4*dp
     +  -1.2d4*dsa
      theta(0,3)=theta(0,3)                                              T0 t3
     +  -0.0025d4*dp
      zeta(0,1)=zeta(0,1)                                                T0 t1
     +  +0.4588d4*dp-0.0485d4*de
     +  +1.1d4*dsa
      zeta(1,1)=zeta(1,1)                                                T1 t1
     +  +0.0038d4*dp
     +  +64.d4*dju+5.2d4*dsa
      zeta(0,2)=zeta(0,2)                                                T0 t2
     +  +0.0009d4*dp
     +  +1.3d4*dsa
      zeta(0,3)=zeta(0,3)                                                T0 t3
     +  +0.0011d4*dp
      z(0,1)=z(0,1)                                                      T0 t1
     +  +0.4588d4*dp-0.0485d4*de
     +  +1.1d4*dsa
      z(1,1)=z(1,1)                                                      T1 t1
     +  +0.0038d4*dp
     +  +64.d4*dju+5.2d4*dsa
      z(0,2)=z(0,2)                                                      T0 t2
     +  +0.0028d4*dp
     +  +49.d4*dju+4.0d4*dsa
      z(0,3)=z(0,3)                                                      T0 t3
     +  +0.0011d4*dp
      epsil(0,0)=epsil(0,0)                                              T0 t0
     +  +de
      epsil(1,0)=epsil(1,0)                                              T1 t0
     +  -2.7d4*dme-286.d4*dve-159.d4*dju-13.0d4*dsa-0.04d4*dne
      epsil(0,1)=epsil(0,1)                                              T0 t1
     +  -2.7d4*dme-286.d4*dve-159.d4*dju-13.0d4*dsa-0.04d4*dne
      epsil(1,1)=epsil(1,1)                                              T1 t1
     +  +1.4d4*dsa
      epsil(2,1)=epsil(2,1)                                              T2 t1
     +  +0.0004d4*dp
      epsil(1,2)=epsil(1,2)                                              T1 t2
     +  +0.0004d4*dp
      omega(0,0)=omega(0,0)                                              T0 t0
     +  +de
      omega(1,0)=omega(1,0)                                              T1 t0
     +  -2.7d4*dme-286.d4*dve-159.d4*dju-13.0d4*dsa-0.04d4*dne
      omega(1,2)=omega(1,2)                                              T1 t2
     +  -0.0005d4*dp
      omega(0,3)=omega(0,3)                                              T0 t3
     +  -0.0003d4*dp
      psi(0,1)=psi(0,1)                                                  T0 t1
     +  +dp-0.0013d4*de
     +  +7.0d4*dme+156.d4*dve-67.d4*dju-13.1d4*dsa-0.09d4*dne
      psi(1,1)=psi(1,1)                                                  T1 t1
     +  +0.0010d4*dp
     +  +1.3d4*dsa
      psi(0,2)=psi(0,2)                                                  T0 t2
     +  -0.0021d4*dp+0.0021d4*de
     +  -36.d4*dju-3.0d4*dsa
      chi(0,1)=chi(0,1)                                                  T0 t1
     +  -0.0012d4*de
     +  +7.7d4*dme+170.d4*dve-73.d4*dju-14.3d4*dsa-0.10d4*dne
      chi(1,1)=chi(1,1)                                                  T1 t1
     +  -0.0057d4*dp+0.0021d4*de
     +  -1.6d4*dme-175.d4*dve-97.d4*dju-8.0d4*dsa-0.03d4*dne
      chi(0,2)=chi(0,2)                                                  T0 t2
     +  -0.0057d4*dp+0.0027d4*de
     +  -1.6d4*dme-175.d4*dve-97.d4*dju-8.0d4*dsa-0.03d4*dne
      chi(2,2)=chi(2,2)                                                  T2 t2
     +  +0.0003d4*dp
      chi(1,3)=chi(1,3)                                                  T1 t3
     +  +0.0003d4*dp
*
*     Creation of output file NEWPRC.DAT.
*
      inquire (file='NEWPRC.DAT',exist=fexist)
      if (fexist) then
         open (nlu,file='NEWPRC.DAT',status='old')
      else
         open (nlu,file='NEWPRC.DAT',status='new')
      endif
      write (nlu,1000) prc0,obl0,rme0,rve0,rma0,rju0,rsa0,rur0,rne0
      write (nlu,1001) ss,sc
      write (nlu,1002) spi,cpi,p
      write (nlu,1003) theta,zeta,z
      write (nlu,1004) epsil,omega,psi,chi
      close (nlu)
*
*     Formats.
*
1000  format ('*'/
     .'*',5x,'Data for numerical expressions of precession with '
     .'following constants :'/
     .'*',5x,'- general precession :                 ',f12.4,' "/1000y'/
     .'*',5x,'- obliquity in J2000 :                 ',f12.4,' "'/
     .'*',5x,'- Ratio  Sun mass / Mercury mass :     ',f12.4/
     .'*',5x,'- Ratio  Sun mass / Venus   mass :     ',f12.4/
     .'*',5x,'- Ratio  Sun mass / E-M Baryc. mass :   328900.5'/
     .'*',5x,'- Ratio  Sun mass / Mars    mass :     ',f12.4/
     .'*',5x,'- Ratio  Sun mass / Jupiter mass :     ',f12.4/
     .'*',5x,'- Ratio  Sun mass / Saturn  mass :     ',f12.4/
     .'*',5x,'- Ratio  Sun mass / Uranus  mass :     ',f12.4/
     .'*',5x,'- Ratio  Sun mass / Neptune mass :     ',f12.4/
     .'*')
1001  format (
     .6x,'data ss/'/
     .4(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data cs/'/
     .4(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/')
1002  format (
     .6x,'data spi/'/
     .3(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data cpi/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data p/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/')
1003  format (
     .6x,'data theta/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data zeta/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data z/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/')
1004  format (6x,'data epsil/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data omega/'/
     .6(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data psi/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/'/
     .6x,'data chi/'/
     .5(5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0,'/)
     .5x,'.',f11.0,'d0,',f10.0,'d0,',f8.0,'d0,',f7.0,'d0,',
     .f6.0,'d0,',f6.0,'d0/')
      return
      end
